Reference for Processing version 1.1+. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, »please let us know. If you prefer a more technical reference, visit the »Processing Javadoc.

Name

movieEvent()
Examples 
import processing.video.*;
Movie myMovie;

void setup() {
  size(200, 200);
  myMovie = new Movie(this, "totoro.mov");
  myMovie.loop();
}

void draw() {
  image(myMovie, 0, 0);
}

// Called every time a new frame is available to read
void movieEvent(Movie m) {
  m.read();
}
import processing.video.*;
Movie myMovie, yourMovie;

void setup() {
  size(200, 200);
  myMovie = new Movie(this, "totoro.mov");
  yourMovie = new Movie(this, "catbus.mov");
  myMovie.play();
  yourMovie.play();
}

void draw() {
  image(myMovie, 0, 0);
  image(yourMovie, 100, 0);  
}

void movieEvent(Movie m) {
  if(m == myMovie) {
    myMovie.read();
  } else if(m == yourMovie) {
    yourMovie.read();
  }
}
Description Called when a new movie frame is available. Use the read() method to capture this frame. If there is more than one movie in the program, movieEvent() is called each time any of the movies has a new frame available. Use an if() to determine which movie is triggering the event. See the above example for implementation details.
Syntax 
void movieEvent(Movie which) {
  statements
}
Parameters
statements any valid statements
which the movie with the event
Usage Web & Application
Related Movie
Updated on June 14, 2010 12:05:23pm EDT

Creative Commons License