#!/bin/csh
#
#    Script file which does ALL of the work!!
#
#    quick_run 0     ==>  reads two_exp_fit_ranges.dat and makes the
#                         fitting scripts
#
#    quick_run 1     ==>  performs all of the fits using the scripts
#                         made by quick_run 0
#
#    quick_run 2     ==>  makes the web pages
#
#    quick_run 3     ==>  makes all of the plots with respect to R
#
#
###########################################

set webpagerun = 1
set webpagename = B30_AR3
set runname = A
set nspacedim = 3
set weborientation = 0
set Nboot = 1024
set Nbootgap = 65

set program1 = /home1/STATIC_POTENTIAL_RESULTS/src/make_su3_scripts
set program2 = /home1/STATIC_POTENTIAL_RESULTS/src/make_su3_gap_scripts
set program3 = /home1/STATIC_POTENTIAL_RESULTS/src/make_web_pages
set program4 = /home1/STATIC_POTENTIAL_RESULTS/src/plot_su3_Rcurves

set a1g = 1
set a1u = 2
set a2g = 3
set a2u = 4
set b1g = 5
set b1u = 6
set b2g = 7
set b2u = 8
set eg  = 9
set eu  = 10

set a1g_cd = 1
set a1u_cd = 2
set a2g_cd = 3 
set a2u_cd = 4 
set eg_cd = 5 
set eu_cd = 6  

set a1g_pd = 1  
set a1u_pd = 2 
set a2g_pd = 3 
set a2u_pd = 4 
set b1g_pd = 5 
set b1u_pd = 6 
set b2g_pd = 7 
set b2u_pd = 8 


if ( $#argv == 0 ) then
  set flag = -2
else
  set flag = $1
endif

set locs         =  ( A1g   Eu   A1g      B1u      B2u      A1g_T   Eu_T )
set runs         =  ( -1    -1    0       0        0        1       1    )
set channels     =  ( $a1g  $eu  $a1g_pd  $b1u_pd  $b2u_pd  $a1g    $eu  )
set levels       =  ( 1     1     1       1        1        1       1    )
set orientations =  ( 0     0     1       1        1        0       0    )

# ***************************************************************************************

if ( $flag == -1 ) then

rm -f A1g/*
rm -f B1u/*
rm -f B2u/*
rm -f Eu/*
rm -f A1g_T/*
rm -f Eu_T/*
rm -f plots/*
rm -f Rlinks/*
rm -f *.html
rm -f *results*.dat

# ***************************************************************************************

else if ( $flag == 0 ) then

foreach count ( 1 2 3 4 5 6 7  )
  if !( -d $locs[$count] ) then
     mkdir $locs[$count]
  endif
  cd $locs[$count]
  $program1 << END
  $Nboot
  $runs[$count]
  $channels[$count]
  $levels[$count]
END
  cd ..
end

foreach count ( 2 3 4 5 6 7  )
  if !( -d $locs[$count] ) then
     mkdir $locs[$count]
  endif
  cd $locs[$count]
  $program2 << END
  $Nbootgap
  $runs[$count]
  $channels[$count]
  $levels[$count]
END
  cd ..
end

# ***************************************************************************************

else if ( $flag == 1 ) then

  foreach count ( 1 2 3 4 5  )
    if ( $orientations[$count] == 0 ) then
       set ending = .csh
    else if ( $orientations[$count] == 1 ) then
       set ending = _PD.csh
    else if ( $orientations[$count] == 2 ) then
       set ending = _CD.csh
    else
       echo "Bad orientation"
       exit
    endif
    cd $locs[$count]
    set runfile = fit_${locs[$count]}
    @ pcount = ${levels[$count]} - 1
    while ( $pcount > 0 )
      set runfile = ${runfile}p
      @ pcount--
      end
    set runfile = ${runfile}${ending}
    $runfile
    cd ..
    end
  foreach count ( 2 3 4 5  )
    if ( $orientations[$count] == 0 ) then
       set ending = .csh
    else if ( $orientations[$count] == 1 ) then
       set ending = _PD.csh
    else if ( $orientations[$count] == 2 ) then
       set ending = _CD.csh
    else
       echo "Bad orientation"
       exit
    endif
    cd $locs[$count]
    set runfile = fit_${locs[$count]}
    @ pcount = ${levels[$count]} - 1
    while ( $pcount > 0 )
      set runfile = ${runfile}p
      @ pcount--
      end
    set runfile = ${runfile}_gap${ending}
    $runfile
    cd ..
    end
    

# **************************************************************************************

else if ( $flag == 2 ) then

if !( -d Rlinks ) then
   mkdir Rlinks
endif
$program3 << END
$cwd
$webpagename
$runname
$nspacedim
$weborientation
END

# ***************************************************************************************

else if ( $flag == 3 ) then

if !( -d plots ) then
   mkdir plots
endif
$program4 << END
$webpagerun
END

# **************************************************************************************

else

   echo " flag is not 0, 1, 2, or 3 --- nothing to do"
   
endif

exit